home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (PO) / Bits and Bytes Volume 10, No. 03 (1988-10)(Apple Computing Enjoyment Society)(Side B).zip / Bits and Bytes Volume 10, No. 03 (1988-10)(Apple Computing Enjoyment Society)(Side B).po / COLOR.LABELS.bas < prev    next >
BASIC Source File  |  1996-12-24  |  4KB  |  64 lines
  1. 50  REM  ***********************************
  2. 100  REM * Color Labels for Imagewriter II *
  3. 110  REM *         Version 1.2             *
  4. 120  REM *       By Joseph Kline           *
  5. 130  REM ***********************************
  6. 140  REM 
  7. 1000  TEXT : HOME :D$ =  CHR$(4): PRINT D$"PR#3": PRINT :ESC$ =  CHR$(27)
  8. 1100  POKE 1403,30: PRINT "Color Labels v1.2"
  9. 1150  FOR X = 1 TO 80: PRINT ".";: NEXT : PRINT 
  10. 1160  PRINT "Imagewriter I or II? (1/[2]) ";: GET IW$:IW =  VAL(IW$): IF IW < >1  THEN IW = 2
  11. 1165  POKE 1403,77: INVERSE : PRINT IW: NORMAL 
  12. 1200  PRINT "How many lines of text per label? (def=3, max=5) ";: GET L$:L =  VAL(L$): IF L = 0  THEN L = 3
  13. 1210  IF L >5  THEN L = 5
  14. 1220  POKE 1403,77: INVERSE : PRINT L: NORMAL 
  15. 1300  PRINT "Would you like the text of each line centered? ([Y]/N) ";: GET M$: IF M$ < >"N"  THEN M$ = "Y"
  16. 1310  POKE 1403,77: INVERSE : PRINT M$: NORMAL 
  17. 1400  PRINT "What character for the border? (def='*') ";: GET B$: IF B$ =  CHR$(13)  THEN B$ = "*"
  18. 1500  IF  LEN(B$) >1  THEN B$ =  LEFT$(B$,1)
  19. 1510  POKE 1403,77: INVERSE : PRINT B$: NORMAL 
  20. 1550  IF IW = 1  THEN BC$ = "": PRINT "Text and Border will be the same color.": GOTO 1900
  21. 1600  PRINT "Text color? (Y)ellow, (R)ed, (B)lue, (O)range, (G)reen, (P)urple (def=Blk) ";: GET TC$:CL$ = TC$: GOSUB 5010:TC$ = CL$
  22. 1610  POKE 1403,76: INVERSE : PRINT CN$: NORMAL 
  23. 1700  PRINT "Border color? (Y)ellow, (R)ed, (B)lue, (O)range, (G)reen, (P)urp (def=Blk) ";: GET BC$:CL$ = BC$: GOSUB 5010:BC$ = CL$
  24. 1710  POKE 1403,76: INVERSE : PRINT CN$: NORMAL 
  25. 1900  PRINT "How many labels per entry? (def=1) ";: GET H$:H =  VAL(H$): IF H$ =  CHR$(13)  THEN H = 1
  26. 1910  IF H <1  THEN H = 1: POKE 1403,77: INVERSE : PRINT H: NORMAL 
  27. 1950  FOR X = 1 TO 80: PRINT ".";: NEXT : PRINT : VTAB 14
  28. 2000  POKE 1403,28: PRINT "1   5   10   15   20": POKE 1403,28: PRINT "|...T....T....T....|"
  29. 2100  FOR X = 1 TO L
  30. 2200  VTAB 15 +X: POKE 1403,19: CALL  -868: PRINT "Line "X"->";: INPUT " ";T$(X)
  31. 2210  IF  LEN(T$(X)) >20  THEN  VTAB 15 +X: CALL  -868: GOTO 2200
  32. 2290  IF M$ = "N"  THEN  GOTO 2320
  33. 2300 A =  LEN(T$(X)): IF A = 20  THEN  GOTO 2350
  34. 2310 J = (20 -A)/2 -1: FOR I = 0 TO J:T$(X) = " " +T$(X): NEXT 
  35. 2320 T$(X) =  LEFT$(T$(X) +"                    ",20)
  36. 2350  VTAB 15 +X: POKE 1403,28: PRINT T$(X)
  37. 2500  NEXT : PRINT 
  38. 2600  INPUT "Correct? ([Y]/N) ";A$: IF A$ < >"N" GOTO 2900
  39. 2610  GOTO 3600
  40. 2900  PRINT D$"PR#1": PRINT : FOR J = 1 TO H
  41. 2905  IF IW = 1  THEN  GOTO 2915
  42. 2910  PRINT ESC$;"a";"2";
  43. 2915  PRINT ESC$; CHR$(113); CHR$(14);ESC$; CHR$(65);
  44. 2920  IF L >3  THEN  PRINT ESC$; CHR$(66);
  45. 2950  IF L <3  THEN  PRINT 
  46. 3020  PRINT BC$;: FOR X = 1 TO 24: PRINT B$;: NEXT : PRINT 
  47. 3025  FOR X = 1 TO L: PRINT B$;" ";TC$;T$(X);" ";BC$;B$: NEXT 
  48. 3040  PRINT BC$;: FOR X = 1 TO 24: PRINT B$;: NEXT : PRINT 
  49. 3045  IF L <2  THEN  PRINT 
  50. 3050  IF L = 4  THEN  PRINT 
  51. 3100  NEXT 
  52. 3500  PRINT D$"PR#0"
  53. 3600  INPUT "Another? ([Y]/N) or (R)eset printer, (Q)uit ";A$
  54. 3610  IF (A$ = "")  OR (A$ = "Y")  THEN  GOTO 2100
  55. 3650  IF (A$ = "R")  OR (A$ = "r")  THEN  GOTO 1000
  56. 3700  HOME : END 
  57. 5000  REM   COLORS FOR IMAGEWRITER II PRINTER
  58. 5010  IF CL$ = "Y"  THEN CL$ = ESC$ +"K" +"1":CN$ = "YEL": RETURN 
  59. 5020  IF CL$ = "R"  THEN CL$ = ESC$ +"K" +"2":CN$ = "RED": RETURN 
  60. 5030  IF CL$ = "B"  THEN CL$ = ESC$ +"K" +"3":CN$ = "BLU": RETURN 
  61. 5040  IF CL$ = "O"  THEN CL$ = ESC$ +"K" +"4":CN$ = "ORA": RETURN 
  62. 5050  IF CL$ = "G"  THEN CL$ = ESC$ +"K" +"5":CN$ = "GRN": RETURN 
  63. 5060  IF CL$ = "P"  THEN CL$ = ESC$ +"K" +"6":CN$ = "PUR": RETURN 
  64. 5070 CL$ = ESC$ +"K" +"0":CN$ = "BLK": RETURN